#! /bin/tcsh -f
####################################################################
#	動物の森プレイヤーアニメーションデータファイルをとってくる
#	$Id: rcp.sh,v 1.4 2000-12-01 18:10:57+09 komatu Exp $
####################################################################

#############使用するファイル名文字列
set decl_file_name="convert.decl"
set decl_file_name2="convert2.decl"
set decl_new_file_name="convert.decl_new"
set decl_new_file_name2="convert2.decl_new"
@ new_file = 1		###新規のファイルを検出するためのフラグ
@ new_file_status = 0		###新規のファイルが最終的にあったことを示すフラグ

#############アニメーションデータのコピー
\cp -f /auto/ikuiku/home/forest/FOREST/model/animal/ply/ply_1_*_anm.c ../shape
\cp -f /auto/ikuiku/home/forest/FOREST/model/animal/ply/ply_1_*.txa ../shape

#############ファイルの初期化
\rm -f $decl_new_file_name
\rm -f $decl_new_file_name2
\touch $decl_new_file_name
\touch $decl_new_file_name2

#############新規のアニメーションデータファイルの検出
foreach ls_label (`\ls -1 ../shape/ply_1_*_anm.c`)
    @ new_file = 1
    foreach msg_label (`echo $ls_label | sed 's:../shape/ply_1_::g' | sed 's/_anm.c//g'`)
	foreach decl_label (`\cat $decl_file_name`)
	    switch($decl_label)
		case $msg_label:
		    @ new_file = 0
		    breaksw
	    endsw
	end
	if ($new_file != 0) then
	    echo $msg_label >>$decl_new_file_name
	    @ new_file_status = 1
	endif
    end
end

#############新規のアニメーションデータファイルがあったことを知らせる
if ($new_file_status != 0) then
    echo "新たなアニメーションファイルの発見！！！！！！！！！！！！！！！"
endif

#############新規のテクスチャアニメーションデータファイルの検出
@ new_file = 1
@ new_file_status = 0
foreach ls_label (`\ls -1 ../shape/ply_1_*.txa`)
    @ new_file = 1
    foreach msg_label (`echo $ls_label | sed 's:../shape/ply_1_::g' | sed 's/.txa//g'`)
	foreach decl_label (`\cat $decl_file_name2`)
	    switch($decl_label)
		case $msg_label:
		    @ new_file = 0
		    breaksw
	    endsw
	end
	if ($new_file != 0) then
	    echo $msg_label >>$decl_new_file_name2
	    @ new_file_status = 1
	endif
    end
end

#############新規のテクスチャアニメーションデータファイルがあったことを知らせる
if ($new_file_status != 0) then
    echo "新たなテクスチャアニメーションファイルの発見！！！！！！！！！！！！！！！"
endif



################rcp.sh end