#! /bin/tcsh -f
################################################################################
#
#	"動物の森"プレイヤー顔のテクスチャデータ変換シェル
#
################################################################################

#############使用するファイル名文字列
set log_file="/tmp/$0.$USER.cnvertlog"

set decl_file_name="convert.decl"
set out_data_file_name="data.c"


#############出力ファイルの初期化
\rm -rf $out_data_file_name


#############ヘッダー部分の出力
echo '#include "m_basic.h"\n' >$out_data_file_name
echo '/* 一番上だけexternで */' >>$out_data_file_name

#############ファイルの変換
@ num = 0

foreach out_label (`\cat $decl_file_name`)
    gdc -c $out_label".out" -w 32 -h 16 -b 4 -y -p -r | tee -a $log_file

    echo "/* $num */" >>$out_data_file_name
    if(  $num == 0 ) then
	echo 'unchar BOY_face_tex_'"$out_label"'[] = {\n' >>$out_data_file_name
    else
	echo 'static unchar BOY_face_tex_'"$out_label"'[] = {\n' >>$out_data_file_name
    endif
    PickupTexFromDiv <$out_label"_div4.c" >>$out_data_file_name
    echo '};\n' >>$out_data_file_name

    echo 'static unshort BOY_face_pallet_'"$out_label"'[] = {\n' >>$out_data_file_name
    PickupPalletFromDiv <$out_label"_div4.c" >>$out_data_file_name
    echo '};\n' >>$out_data_file_name

    \rm -f $out_label"_div4.c"
    @ num += 1
end


#############フッタ─部分の出力
echo >>$out_data_file_name


#####エラーのチェック
grep -i 'Error' $log_file > /dev/null
if($status == 0) then
    echo "\033[31m"
    echo "ERROR"
    echo "\033[m"
    exit 1
endif

grep 'エラー' $log_file > /dev/null
if($status == 0) then
    echo "\033[31m"
    echo "ERROR"
    echo "\033[m"
    exit 1
endif

\rm -rf $log_file

############# end convert.sh