#! /bin/tcsh
################################################################################
#
#	"動物の森"プレイヤー服のテクスチャデータ変換シェル
#
################################################################################

#############使用するファイル名文字列
set log_file="/tmp/$0.$USER.cnvertlog"

set decl_file_name="convert.decl"
set tex_out_file_name="../tex_boy.c"
set pallet_out_file_name="../pallet_boy.c"
set enum_out_file_name="../tex_boy.enum"
set tex_dir="CLOTH_TEX"

#############出力ファイルの初期化
cd $tex_dir
\rm -f $log_file
\rm -f $tex_out_file_name
\rm -f $pallet_out_file_name
\rm -f $enum_out_file_name

#############ヘッダー部分の出力

echo '#include "m_basic.h"\n' >>$tex_out_file_name
echo 'unchar BOY_tex_data[] = {' >>$tex_out_file_name

echo '#include "m_basic.h"\n' >>$pallet_out_file_name
echo 'unshort BOY_pallet_data[] = {' >>$pallet_out_file_name

#############ファイルの変換
@ num = 0

foreach out_label (`\cat $decl_file_name`)
    gdc -c $out_label".out" -w 32 -h 32 -b 4 -y -p -r | tee -a $log_file

    echo "	/* $num */" >>$tex_out_file_name
    PickupTexFromDiv <$out_label"_div4.c" >>$tex_out_file_name

    echo "	/* $num */" >>$pallet_out_file_name
    PickupPalletFromDiv <$out_label"_div4.c" >>$pallet_out_file_name

    echo "	M_PLAYER_PATTERN_$out_label,	/* $num */" >>$enum_out_file_name

    \rm -f $out_label"_div4.c"
    @ num += 1
end


#############フッタ─部分の出力
echo '};' >>$tex_out_file_name
echo '};' >>$pallet_out_file_name
cd "../"

#####エラーのチェック
grep -i 'Error' $log_file > /dev/null
if($status == 0) then
    echo "\033[31m"
    echo "ERROR"
    echo "\033[m"
    exit 1
endif

grep 'エラー' $log_file > /dev/null
if($status == 0) then
    echo "\033[31m"
    echo "ERROR"
    echo "\033[m"
    exit 1
endif