#! /bin/tcsh
# -*- mode: perl; -*-
####################################################################
#	動物の森”用メッセージ変換
####################################################################

#####使用するファイル名
set data_file_bmp="message_data.bmp"
set data_file_c="message_data.c"
set tmp_data_file_c="tmp_message_data.c"
set table_file_bmp="message_data_table.bmp"
set table_file_c="message_data_table.c"
set tmp_table_file_c="tmp_message_data_table.c"
set enum_tmp_file="message_data_enum.h.tmp"
set enum_file="message_data_enum.h"
set decl_file="convert.decl"
set decl_msg_euc_unix_file=$decl_file.msg.euc.unix


#####定義ファイルのチェック
if(!(-f $decl_file)) then
    echo "定義ファイルがオープン出来ません $decl_file"
    exit 1
endif


#####メッセージリストファイルの作成
\rm -f $decl_msg_euc_unix_file
foreach label (`\cat $decl_file`)
    echo "$label.msg.euc.unix" >>$decl_msg_euc_unix_file
end


#####メッセージデータを"UNIXコード"かつ"EUCコード"に変換したテンポラリーファイルの作成
foreach label (`\cat $decl_file`)
    nkf -e $label.msg | to_unix >$label.msg.euc.unix
###    nkf -e $label.msg >$label.msg.euc
###    to_unix <$label.msg.euc >$label.msg.euc.unix
###    \rm -f $label.msg.euc
end


#####メッセージデータの変換
forest_m_nes -b $data_file_bmp $table_file_bmp $enum_tmp_file $decl_msg_euc_unix_file

echo '#include "m_basic.h"' > $tmp_data_file_c
echo "\n" >> $tmp_data_file_c
echo "const unsigned char MSG_data[] = {" >> $tmp_data_file_c
echo -n "@ " >> $tmp_data_file_c
bintoc $data_file_bmp >> $tmp_data_file_c

echo '#include "m_basic.h"' > $tmp_table_file_c
echo "\n" >> $tmp_table_file_c
echo "const unsigned char MSG_TABLE_data[] = {" >> $tmp_table_file_c
echo -n "@ " >> $tmp_table_file_c
bintoc $table_file_bmp >> $tmp_table_file_c

# (@行を削除)
sed '/^@/d' $tmp_data_file_c > $data_file_c
sed '/^@/d' $tmp_table_file_c > $table_file_c

# enum から define へ 変換 (コンパイル時間短縮のため)
ToMsgDataEnum.pl $enum_tmp_file > $enum_file

#####テンポラリーファイルの削除
\rm -f $tmp_data_file_c
\rm -f $tmp_table_file_c
\rm -f $decl_msg_euc_unix_file
foreach label (`\cat $decl_file`)
    \rm -f $label.msg.euc.unix
end
\rm $enum_tmp_file


##### ＨＰ更新
# rcp $enum_file forest@srd-server:/home/forest/public_html/programmer/doc