﻿Shader "Custom/Jace HUD Transparent"
{
    Properties
    {
    	_Color("Color (placeholder)", Color) = (1,1,1,0)
        _MainTex("Camera RT", 2D) = "white" {}
        _Range("Range (radius from center)", Range(0.0, 1.0)) = 0.35
        _Offset ("HUD Offset", Vector) = (0.0, 0.0, 0.0, 0.0)
        _Convergence("Stereo Convergence", float) = 0.07648
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" "Queue"="Overlay" }
        LOD 100

     	Cull off
        Zwrite Off
        
        Ztest Always
        
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            half _Range;
            half _Convergence;
            half4 _Offset;

            v2f vert (appdata v)
            {
                v2f o;
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);

                // Stereo separation
				#if UNITY_SINGLE_PASS_STEREO
					float4 abspos = v.vertex + float4(_Convergence * (0.5 - unity_StereoEyeIndex), 0, 0, 0);
				#else
					float4 abspos = v.vertex;
				#endif
	
                // Manual offset
				abspos.xyz += _Offset.xyz;

				// Transform vertices in front of camera
				float4 worldPos = mul(unity_CameraToWorld, abspos);
				float4 objectPos = mul(unity_WorldToObject, worldPos);
				
				o.vertex = UnityObjectToClipPos(objectPos);

                // Snap vertices to origin if out of specified range, so other players can't see it
				float4 dist = distance(_WorldSpaceCameraPos, mul(unity_ObjectToWorld, float4(0,0,0,1)));
				o.vertex = o.vertex - o.vertex * step(_Range, dist);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                return col;
            }
            ENDCG
        }
    }
}
